\ animation - boxes bouncing off picture
\ with lines between boxes
\ Lab 2 Summer 2015 - boxes replaced by emoji
\ 👷👸👹👺👻👼👽👾👿💀💁💂💃
\ Roger's day off
\ 🇬🇧🌍📱🔌😴💤⏰📢💭🚿👕☕️🍳💆🏽🕧🚙🏃🏻🕛⛅️🌱🎾👊🏼✨🚿🍓🚗🍝🍖🍫🍦☕️😄💆🏽📺🎾😀☀️💭💡🎯😋👋🏼🔚
\ Andy's wedding day
\ 🌞☔😂👔💅💇😂👰😂🚗💒💃👫🙏💍💏👏📝🎹📷🎥🚗🍷🍴🎂🎊🎉👯🎶🎤🍹🍻🍷🍺🍩🍦🍷🍹🍸🍺🌙❤💕😘💤💤💤💤💤💤💤

const numboxes=10,emojisize=30,delay=50;

var xbox{numboxes},ybox{numboxes},
    xincr{numboxes},yincr{numboxes},
    emojinum{numboxes},
    i,j,picnum;

procedure movebox(i); \ Move box i, bouncing off wall if needed
  var bounced;
  begin
    bounced:=0; \ flag for need to change emoji
    xbox{i}:=xbox{i}+xincr{i};
    if xbox{i}<10 then
      if xincr{i}<0 then
        begin
          xincr{i}:= -xincr{i};
          bounced:=1
        end;
    if xbox{i}>490 then
      if xincr{i}>0 then
        begin
          xincr{i}:= -xincr{i};
          bounced:=1
        end;
    ybox{i}:=ybox{i}+yincr{i};
    if ybox{i}<10 then
      if yincr{i}<0 then
        begin
          yincr{i}:= -yincr{i};
          bounced:=1
        end;
    if ybox{i}>290 then
      if yincr{i}>0 then
        begin
          yincr{i}:= -yincr{i};
          bounced:=1
        end;
    if bounced=1 then
      begin
        emojinum{i}:=emojinum{i}+1;
        if emojinum{i}>emojicount then
          emojinum{i}:=1
      end
  end;

begin
  call cvclear;
  picnum:=1;
  i:=0;
  while i<numboxes do
    begin
      call cvclick;
      xbox{i}:=cvx;
      ybox{i}:=cvy;
      emojinum{i}:=1; 
      call emojidraw(emojinum{i},xbox{i},ybox{i},emojisize);
      xincr{i}:=5;
      yincr{i}:=5;
      i:=i+1
    end;
  call cvasclick;
  while 1=1 do
    begin
      while cvx<0 do \ Continue while cursor off canvas
        begin
          call cvclear;
          i:=0;
          while i<numboxes do
            begin \ Move all the boxes, bouncing if needed
              call emojidraw(emojinum{i},xbox{i},ybox{i},emojisize);
              call movebox(i);
              i:=i+1
            end;
          call wait(delay)
       end;
      while cvx> -1 do
        begin
          call cvclear;
          call cvdraw(picnum,cvx-40,cvy-50,80,100);
          i:=0;
          while i<numboxes do \ Continue while cursor over canvas
            begin
              call emojidraw(emojinum{i},xbox{i},ybox{i},emojisize);
              call movebox(i);
              \ Detect collision with picture and bounce
              if xbox{i}>cvx-45 then
                if xbox{i}<cvx+45 then
                  if ybox{i}>cvy-55 then
                    if ybox{i}<cvy+55 then
                      begin
                        xincr{i}:= -xincr{i};
                        yincr{i}:= -yincr{i}
                      end;
              i:=i+1
            end;

          i:=0;
          while i<numboxes do \ draw lines
            begin
              j:=i+1;
              while j<numboxes do
                begin
                  call cvline(xbox{i},ybox{i},xbox{j},ybox{j});
                  j:=j+1
                end;
              i:=i+1
            end;

          call wait(delay);
          if cvclickx>-1 then
            begin
              call cvasclick;
              picnum:=picnum+1;
              if picnum=4 then
                picnum:=1
            end
        end;
      call cvclear
    end
end.